@ECHO Off
rem;  Check for menu request (use one-line MENU.BAT: "@c:\autoexec menu")
if %1.==menu. goto menu

rem;  setup standard DOS environment here...

PATH C:\NET;C:\DOS;C:\WINDOWS;C:\BIN
PROMPT $p$g

SET NWLANGUAGE=ENGLISH

rem;  load any non-network-related drivers (such as a disk cache) here...
rem  LH C:\MOUSE\MOUSE.COM 
rem  NWCACHE 3072 /LEND=OFF

:menu
c:
set config=
echo.
echo The following menu is fully contained within AUTOEXEC.BAT.  It uses the
echo DOS "CHOICE" command to offer:
echo.
echo           [A]  TCP/IP - driver shares modem with Windows
echo           [B]  TCP/IP - modem is dedicated to driver  
echo           [C]  TCP/IP & NetWare - modem is dedicated to driver
echo           [D]  LAN - TCP/IP & NetWare
echo           [E]  LAN - TCP/IP only
echo           [F]  All of the above - TCP/IP uses LAN and shares modem
echo           [G]  None of the above - Exit to DOS prompt / do nothing
echo.
CHOICE /C:abcdefg /N  Please select:  
rem;  Determine choice, set "config" variable, goto load lsl
if errorlevel 7 goto end
if errorlevel 6 set config=both
if %config%.==both. goto LSL
if errorlevel 5 set config=lan_tcp
if %config%.==lan_tcp. goto LSL
if errorlevel 4 set config=lan_tcp_nw
if %config%.==lan_tcp_nw. goto LSL
if errorlevel 3 set config=modem_tcp_nw
if %config%.==modem_tcp_nw. echo.
if %config%.==modem_tcp_nw. echo This option requires an unreleased version of the
if %config%.==modem_tcp_nw. echo NetWare DOS and MS Windows Requester.  Sorry.
if %config%.==modem_tcp_nw. pause
if %config%.==modem_tcp_nw. goto menu
rem  delete the previous 5 lines to activate with VLM v1.11 or later
if %config%.==modem_tcp_nw. goto lsl
if errorlevel 2 set config=modem_tcp
if %config%.==modem_tcp. goto LSL
if errorlevel 1 set config=modem_share_tcp
:LSL
c:
cd \net
lh lsl 
goto %config%
:LAN_TCP_NW
:LAN_TCP
set NETCFG=NET.CFG
rem  Verify that the correct ODI driver is being loaded.
loadhigh ne2000
tcpip
if %config%.==lan_tcp. goto end
goto NetWare
:MODEM_SHARE_TCP
:MODEM_TCP
:MODEM_TCP_NW
set NETCFG=NET.CFG
if %config%.==modem_share_tcp. slip_ppp 
if not %config%.==modem_share_tcp. slip_ppp /e
tcpip
if %config%.==modem_tcp_nw. goto NetWare
rem  If using the LWP v4.2 NFS Client over the modem, load it here
rem  (but only when NOT sharing modem with MS Windows COMM.DRV).
rem  if not %config%.==modem_share_tcp. lwprpc.com
rem  if not %config%.==modem_share_tcp. lwpnfs.com nb3 /r:2048 /w:2048
goto end
:BOTH
set NETCFG=NET.CFG
lsl /c=c:\net\%NETCFG%
slip_ppp 
loadhigh ne2000
tcpip
:NetWare
if %config%.==modem_tcp_nw. loadhigh iptunnel
cd \NWCLIENT
loadhigh ipxodi /c=c:\net\%NETCFG%
vlm /c=c:\net\%NETCFG%
:end
cd \
echo.
CHOICE Would you like to start Windows now
if not errorlevel 2 win
echo.
ver
echo.
